c_ ---------------------------------------------------------------------
c_ RCS lines preceded by "c_ "
c_ ---------------------------------------------------------------------
c_
c_ $Source: /www/html/ipsl/OCMIP/phase2/simulations/CFC/distrib/RCS/write_nc_SurfTS_year.f,v $
c_ $Revision: 2.2 $
c_ $Date: 1999/10/19 12:25:41 $   ;  $State: Exp $
c_ $Author: jomce $ ;  $Locker:  $
c_
c_ ---------------------------------------------------------------------
c_ $Log: write_nc_SurfTS_year.f,v $
c_ Revision 2.2  1999/10/19 12:25:41  jomce
c_ Delete some associate attributes (no longer needed for GAP)
c_ Added string to identify RCS filename and revision
c_
c_ Revision 2.1  1999/04/29 11:55:04  orr
c_ Now GDT 1.2 compatible!!
c_ Added argument "production"
c_ Deleted arguments lon,bounds_lon,lat,bounds_lat.
c_
c_ Revision 1.4  1998/10/29 10:46:48  brocksce
c_ Change write of time and bounds_time arrays to avoid unreset
c_ values with some compilers (?!).
c_
c_ Revision 1.3  1998/09/10 09:19:07  brocksce
c_ Change the construction of the filename (group remplace group(1:3)),
c_ Add missing value attribute for SST and SSS variable.
c_
c_ Revision 1.2  1998/08/26 12:13:18  brocksce
c_ Fixed convention error on two-dimensional bound arrays
c_ (confusion between C and FORTRAN notations).
c_
c_ Revision 1.1  1998/07/21 16:55:54  jomce
c_ Initial revision
c_
c_ ---------------------------------------------------------------------
c_

C***********************************************************************
C
C NAME: WRITE_NC_SurfTS_year
C
C INPUT:
C       group= group code (ex: IPSL)
C       production= production (model and version ex: OPA 8.1) 
C       imt= dimension
C       jmt= dimension
C       year= year of simulation [years]
C       nb_seconds_per_year= following your model year 
C       nb_timesteps_per_year= following your model timestep 
C
C       SST= monthly sea surface temperature [degrees C]
C       SSS= monthly sea surface salinity [psu]
C
C OUTPUT FILE:
C       A netcdf file (clobbed if exists) with
C       the filename group_SurfTS_year.nc
C
C***********************************************************************

	SUBROUTINE WRITE_NC_SurfTS_year(
     &	group,production,
     &	imt,jmt,
     &	year,nb_seconds_per_year,nb_timesteps_per_year,
     &	SST,SSS)

C No implicit declarations
        IMPLICIT NONE

C Arguments
	CHARACTER*(*) group
	CHARACTER*(*) production
	INTEGER*4 imt,jmt
	INTEGER*4 year
	INTEGER*4 nb_seconds_per_year
	INTEGER*4 nb_timesteps_per_year
        REAL*4 time(12)
	REAL*4 SST(imt,jmt,12)
	REAL*4 SSS(imt,jmt,12)

C Constants
	REAL*4 missing_value
	PARAMETER (missing_value=-1.E+34)

C Local variables
	CHARACTER*256 string256,filename
	CHARACTER*4 string4
        INTEGER*4 I

C Function
        INTEGER*4 LEN_TRIM

C NetCDF variables
	INCLUDE 'netcdf.inc'
	INTEGER*4 NC_ID
	INTEGER*4 STATUS
	INTEGER*4 LON_DIM
	INTEGER*4 LAT_DIM
	INTEGER*4 TIME_DIM,TIME_ID
	INTEGER*4 SST_ID,SSS_ID
	INTEGER*4 DIMS_3D(3)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Build the NetCDF filename 
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        WRITE(string4,'(I4.4)') year
        filename=group//'_SurfTS_'//string4//'.nc'

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Open the NetCDF file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_CREATE(filename,NF_CLOBBER,NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define dimensions 
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_DEF_DIM(NC_ID,'x',imt,LON_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_DEF_DIM(NC_ID,'y',jmt,LAT_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_DEF_DIM(NC_ID,'time',12,TIME_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define variables
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        STATUS=NF_DEF_VAR(NC_ID,'time',NF_FLOAT,
     &	1,TIME_DIM,TIME_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	DIMS_3D(1)=LON_DIM
	DIMS_3D(2)=LAT_DIM
	DIMS_3D(3)=TIME_DIM
	STATUS=NF_DEF_VAR(NC_ID,'SST',NF_FLOAT,
     &	3,DIMS_3D,SST_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	STATUS=NF_DEF_VAR(NC_ID,'SSS',NF_FLOAT,
     &	3,DIMS_3D,SSS_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define global attributes
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        string256='$RCSfile: write_nc_SurfTS_year.f,v $' 
     &           //'$Revision: 2.2 $'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,
     &  'output_routine',LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='GDT 1.2'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'Conventions',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=filename
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'file_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=group//'_grid.nc'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'associate_file',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='OCMIP'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'project',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=group
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'institution',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=production
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'production',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define variable attributes
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        string256='year and seasonal phase'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,TIME_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='calendar_month as %Y%m.%f'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,TIME_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_INT(NC_ID,TIME_ID,'nb_seconds_per_year',
     &	NF_INT,1,nb_seconds_per_year)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_INT(NC_ID,TIME_ID,'nb_timesteps_per_year',
     &  NF_INT,1,nb_timesteps_per_year)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	string256='Sea Surface Temperature'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,SST_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	string256='degrees C'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,SST_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_REAL(NC_ID,SST_ID,'missing_value',
     &	NF_FLOAT,1,missing_value)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	string256='Sea Surface Salinity'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,SSS_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	string256='psu'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,SSS_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_REAL(NC_ID,SSS_ID,'missing_value',
     &	NF_FLOAT,1,missing_value)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C End of define mode
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_ENDDEF(NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Write data to file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        DO I=1,12
                time(I)=year*100. +I - 0.5
        ENDDO	
	
	STATUS=NF_PUT_VAR_REAL(NC_ID,TIME_ID,time)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	STATUS=NF_PUT_VAR_REAL(NC_ID,SST_ID,SST)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	STATUS=NF_PUT_VAR_REAL(NC_ID,SSS_ID,SSS)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Close the NetCDF file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_CLOSE(NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	END