c_ ---------------------------------------------------------------------
c_ RCS lines preceded by "c_ "
c_ ---------------------------------------------------------------------
c_
c_ $Source: /www/html/ipsl/OCMIP/phase2/simulations/CFC/distrib/RCS/write_nc_MaskAreaBathy.f,v $
c_ $Revision: 2.2 $
c_ $Date: 1999/10/19 12:25:41 $   ;  $State: Exp $
c_ $Author: jomce $ ;  $Locker:  $
c_
c_ ---------------------------------------------------------------------
c_ $Log: write_nc_MaskAreaBathy.f,v $
c_ Revision 2.2  1999/10/19 12:25:41  jomce
c_ Delete some associate attributes (no longer needed for GAP)
c_ Added string to identify RCS filename and revision
c_
c_ Revision 2.1  1999/04/29 11:44:58  orr
c_ Now GDT 1.2 compatible!!!
c_ Added argument "production"
c_
c_ Revision 1.3  1998/09/10 09:22:26  brocksce
c_ Add missing value attribute for BATHY variable.
c_
c_ Revision 1.2  1998/08/26 12:09:12  brocksce
c_ Fixed convention error on two-dimensional bound arrays
c_ (confusion between C and FORTRAN notations).
c_
c_ Revision 1.1  1998/07/21 16:55:54  jomce
c_ Initial revision
c_
c_ ---------------------------------------------------------------------
c_

C***********************************************************************
C
C NAME: WRITE_NC_MaskAreaBathy
C
C INPUT:
C       group= group code (ex: IPSL)
C       production= production (model and version ex: OPA 8.1)
C       imt= dimension
C       jmt= dimension
C       kmt= dimension
C       lon= longitude axis [degrees East]
C       bounds_lon= boundaries array [degrees East]
C                 = bounds_lon(i,j,1,1) represents the lower left boundary
C                 = bounds_lon(i,j,2,1) represents the lower right boundary
C                 = bounds_lon(i,j,1,2) represents the upper left boundary
C                 = bounds_lon(i,j,2,2) represents the upper right boundary
C       lat= latitude axis [degrees North]
C       bounds_lat= boundaries array [degrees North]
C                 = bounds_lat(i,j,1,1) represents the lower left boundary
C                 = bounds_lat(i,j,2,1) represents the lower right boundary
C                 = bounds_lat(i,j,1,2) represents the upper left boundary
C                 = bounds_lat(i,j,2,2) represents the upper right boundary
C       depth= depth axis [meters]
C       bounds_depth= boundaries array [meters]
C                   = bounds_dept(k,1) represents the lower boundary
C                   = bounds_dept(k,2) represents the upper boundary
C
C       MASK= Mask Land/Ocean at tracer points [0/1]
C       AREA= Surface Area of tracer cells [m^2]
C       BATHY= Bathymetry [m]
C
C OUTPUT FILE:
C       A netcdf file (clobbed if exists) with
C       the filename group_MaskAreaBathy.nc
C
C***********************************************************************

	SUBROUTINE WRITE_NC_MaskAreaBathy(
     &	group,production,
     &	imt,jmt,kmt,
     &	lon,bounds_lon,lat,bounds_lat,depth,bounds_depth,
     &	MASK,AREA,BATHY)

C No implicit declarations
        IMPLICIT NONE

C Arguments
	CHARACTER*(*) group
	CHARACTER*(*) production
	INTEGER*4 imt,jmt,kmt
        REAL*4 lon(imt,jmt),bounds_lon(imt,jmt,2,2)
        REAL*4 lat(imt,jmt),bounds_lat(imt,jmt,2,2)
	REAL*4 depth(kmt),bounds_depth(kmt,2)
	REAL*4 MASK(imt,jmt,kmt)
	REAL*4 AREA(imt,jmt)
	REAL*4 BATHY(imt,jmt)

C Constants
        REAL*4 missing_value
        PARAMETER (missing_value=-1.E+34)

C Local variables
	CHARACTER*256 string256,filename

C Function
        INTEGER*4 LEN_TRIM

C NetCDF variables
	INCLUDE 'netcdf.inc'
	INTEGER*4 NC_ID
	INTEGER*4 STATUS
	INTEGER*4 LON_DIM,LON_ID
	INTEGER*4 LAT_DIM,LAT_ID
	INTEGER*4 DEPTH_DIM,DEPTH_ID
        INTEGER*4 TWO_DIM
        INTEGER*4 BOUNDS_LON_ID
        INTEGER*4 BOUNDS_LAT_ID
	INTEGER*4 BOUNDS_DEPTH_ID
	INTEGER*4 MASK_ID,AREA_ID,BATHY_ID
	INTEGER*4 DIMS_2D(2)
	INTEGER*4 DIMS_3D(3)
	INTEGER*4 DIMS_4D(4)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Build the NetCDF filename
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        filename=group//'_MaskAreaBathy.nc'

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Open the NetCDF file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_CREATE(filename,NF_CLOBBER,NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define dimensions 
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_DEF_DIM(NC_ID,'x',imt,LON_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_DEF_DIM(NC_ID,'y',jmt,LAT_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_DEF_DIM(NC_ID,'depth',kmt,DEPTH_DIM)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_DEF_DIM(NC_ID,'two',2,TWO_DIM)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define variables
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        DIMS_2D(1)=LON_DIM
        DIMS_2D(2)=LAT_DIM
        STATUS=NF_DEF_VAR(NC_ID,'lon',NF_FLOAT,
     &  2,DIMS_2D,LON_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        DIMS_4D(1)=LON_DIM
        DIMS_4D(2)=LAT_DIM
        DIMS_4D(3)=TWO_DIM
        DIMS_4D(4)=TWO_DIM
        STATUS=NF_DEF_VAR(NC_ID,'bounds_lon',NF_FLOAT,
     &  4,DIMS_4D,BOUNDS_LON_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        STATUS=NF_DEF_VAR(NC_ID,'lat',NF_FLOAT,
     &  2,DIMS_2D,LAT_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        STATUS=NF_DEF_VAR(NC_ID,'bounds_lat',NF_FLOAT,
     &  4,DIMS_4D,BOUNDS_LAT_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        STATUS=NF_DEF_VAR(NC_ID,'depth',NF_FLOAT,
     &	1,DEPTH_DIM,DEPTH_ID)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	DIMS_2D(1)=DEPTH_DIM
	DIMS_2D(2)=TWO_DIM
	STATUS=NF_DEF_VAR(NC_ID,'bounds_depth',NF_FLOAT,
     &	2,DIMS_2D,BOUNDS_DEPTH_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	DIMS_3D(1)=LON_DIM
	DIMS_3D(2)=LAT_DIM
	DIMS_3D(3)=DEPTH_DIM
	STATUS=NF_DEF_VAR(NC_ID,'MASK',NF_FLOAT,
     &	3,DIMS_3D,MASK_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	DIMS_2D(1)=LON_DIM
	DIMS_2D(2)=LAT_DIM
	STATUS=NF_DEF_VAR(NC_ID,'AREA',NF_FLOAT,
     &	2,DIMS_2D,AREA_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
	DIMS_2D(1)=LON_DIM
	DIMS_2D(2)=LAT_DIM
	STATUS=NF_DEF_VAR(NC_ID,'BATHY',NF_FLOAT,
     &	2,DIMS_2D,BATHY_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define global attributes
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        string256='$RCSfile: write_nc_MaskAreaBathy.f,v $' 
     &           //'$Revision: 2.2 $'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,
     &  'output_routine',LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='GDT 1.2'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'Conventions',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=filename
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'file_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=group//'_grid.nc'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'associate_file',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='OCMIP'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'project',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=group
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'institution',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256=production
        STATUS=NF_PUT_ATT_TEXT(NC_ID,NF_GLOBAL,'production',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Define variable attributes
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
        string256='Longitude'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LON_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='degrees_east'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LON_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_REAL(NC_ID,LON_ID,'modulo',
     &	NF_FLOAT,1,360.0)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='circular'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LON_ID,'topology',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='bounds_lon'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LON_ID,'bounds',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='Latitude'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LAT_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='degrees_north'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LAT_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='bounds_lat'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,LAT_ID,'bounds',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='Depth below the surface'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,DEPTH_ID,'long_name',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='meters'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,DEPTH_ID,'units',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='down'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,DEPTH_ID,'positive',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='bounds_depth'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,DEPTH_ID,'bounds',
     &	LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='Mask Land/Ocean'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,MASK_ID,'long_name',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='0/1'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,MASK_ID,'units',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='Surface Area of cells'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,AREA_ID,'long_name',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        string256='m^2'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,AREA_ID,'units',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C---------------------------------------------------------
        string256='Bathymetry'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,BATHY_ID,'long_name',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	string256='m'
        STATUS=NF_PUT_ATT_TEXT(NC_ID,BATHY_ID,'units',
     &  LEN_TRIM(string256),string256)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_ATT_REAL(NC_ID,BATHY_ID,'missing_value',
     &  NF_FLOAT,1,missing_value)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C End of define mode
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_ENDDEF(NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Write data to file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_PUT_VAR_REAL(NC_ID,LON_ID,lon)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_VAR_REAL(NC_ID,BOUNDS_LON_ID,bounds_lon)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)
	
	STATUS=NF_PUT_VAR_REAL(NC_ID,LAT_ID,lat)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

        STATUS=NF_PUT_VAR_REAL(NC_ID,BOUNDS_LAT_ID,bounds_lat)
        IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_PUT_VAR_REAL(NC_ID,DEPTH_ID,depth)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_PUT_VAR_REAL(NC_ID,BOUNDS_DEPTH_ID,bounds_depth)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_PUT_VAR_REAL(NC_ID,MASK_ID,MASK)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_PUT_VAR_REAL(NC_ID,AREA_ID,AREA)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	STATUS=NF_PUT_VAR_REAL(NC_ID,BATHY_ID,BATHY)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
C Close the NetCDF file
C~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
	STATUS=NF_CLOSE(NC_ID)
	IF (STATUS.NE.NF_NOERR) CALL HANDLE_ERRORS(STATUS)

	END