c_ ---------------------------------------------------------------------
c_ RCS lines preceded by "c_ "
c_ ---------------------------------------------------------------------
c_
c_ $Source: /www/html/ipsl/OCMIP/phase2/simulations/CFC/boundcond/RCS/sol_cfc.f,v $
c_ $Revision: 1.2 $
c_ $Date: 1998/07/17 07:37:02 $   ;  $State: Exp $
c_ $Author: jomce $ ;  $Locker:  $
c_
c_ ---------------------------------------------------------------------
c_ $Log: sol_cfc.f,v $
c_ Revision 1.2  1998/07/17 07:37:02  jomce
c_ Fixed slight bug in units conversion: converted 1.0*e-12 to 1.0e-12
c_ following warning from Matthew Hecht at NCAR.
c_
c_ Revision 1.1  1998/07/07 15:22:00  orr
c_ Initial revision
c_
c_ ---------------------------------------------------------------------
c_
      REAL FUNCTION sol_cfc(pt,ps,kn)
c-------------------------------------------------------------------
c
c     CFC 11 and 12 Solubilities in seawater
c     ref: Warner & Weiss (1985) , Deep Sea Research, vol32
c
c     pt:       temperature (degre Celcius)
c     ps:       salinity    (o/oo)
c     kn:       11 = CFC-11, 12 = CFC-12
c     sol_cfc:  in mol/m3/pptv
c               1 pptv = 1 part per trillion = 10^-12 atm = 1 picoatm

c
c     J-C Dutay - LSCE
c-------------------------------------------------------------------

      REAL    pt, ps,ta,d
      REAL a1 ( 11: 12), a2 ( 11: 12), a3 ( 11: 12), a4 ( 11: 12)
      REAL b1 ( 11: 12), b2 ( 11: 12), b3 ( 11: 12)

      INTEGER kn

cc
cc coefficient for solubility in  mol/l/atm
cc ----------------------------------------
c
c     for CFC 11
c     ----------
      a1 ( 11) = -229.9261
      a2 ( 11) =  319.6552
      a3 ( 11) =  119.4471
      a4 ( 11) =   -1.39165
      b1 ( 11) =   -0.142382
      b2 ( 11) =    0.091459
      b3 ( 11) =   -0.0157274
c    
c     for CFC/12
c     ----------
      a1 ( 12) = -218.0971
      a2 ( 12) =  298.9702
      a3 ( 12) =  113.8049
      a4 ( 12) =   -1.39165
      b1 ( 12) =   -0.143566
      b2 ( 12) =    0.091015
      b3 ( 12) =   -0.0153924
c

      ta       = ( pt + 273.16)* 0.01
      d    = ( b3 ( kn)* ta + b2 ( kn))* ta + b1 ( kn)
c
c
      sol_cfc 
     $    = exp ( a1 ( kn)
     $    +       a2 ( kn)/ ta 
     $    +       a3 ( kn)* alog ( ta )
     $    +       a4 ( kn)* ta * ta  + ps* d )
c
c     conversion from mol/(l * atm) to mol/(m^3 * atm) 
c     ------------------------------------------------
      sol_cfc = 1000. * sol_cfc
c
c     conversion from mol/(m^3 * atm) to mol/(m3 * pptv) 
c     --------------------------------------------------
      sol_cfc = 1.0e-12 * sol_cfc

      END