c_ ---------------------------------------------------------------------
c_ RCS lines preceded by "c_ "
c_ ---------------------------------------------------------------------
c_
c_ $Source: /home/orr/WWW/Biotic/boundcond/RCS/o2sato.f,v $ 
c_ $Revision: 1.1 $
c_ $Date: 1999/03/22 12:57:48 $   ;  $State: Exp $
c_ $Author: orr $ ;  $Locker:  $
c_
c_ ---------------------------------------------------------------------
c_ $Log: o2sato.f,v $
c_ Revision 1.1  1999/03/22 12:57:48  orr
c_ Initial revision
c_
c_ ---------------------------------------------------------------------
c_ 
      function o2sato(T,S)
c
C ********************************************************************
C                                     
C Computes the oxygen saturation concentration at 1 atm total pressure
c in mol/m^3 given the temperature (t, in deg C) and the salinity (s,
c in permil). 
C
C FROM GARCIA AND GORDON (1992), LIMNOLOGY and OCEANOGRAPHY.
C THE FORMULA USED IS FROM PAGE 1310, EQUATION (8).
c
C *** NOTE: THE "A3*TS^2" TERM (IN THE PAPER) IS INCORRECT. ***
C *** IT SHOULDN'T BE THERE.                                ***
C
C o2sato IS DEFINED BETWEEN T(freezing) <= T <= 40(deg C) AND
c 0 permil <= S <= 42 permil
C C
C CHECK VALUE:  T = 10.0 deg C, S = 35.0 permil, 
c o2sato = 0.282015 mol/m^3
C
C ********************************************************************
c
      DATA A0/ 2.00907   /,A1/ 3.22014   /, A2/ 4.05010 /,
     $     A3/ 4.94457   /,A4/-2.56847E-1/, A5/ 3.88767 /
      DATA B0/-6.24523E-3/,B1/-7.37614E-3/,
     $     B2/-1.03410E-2/,B3/-8.17083E-3/
      DATA C0/-4.88682E-7/
C
      TT  = 298.15-T
      TK  = 273.15+T
      TS  = LOG(TT/TK)
      TS2 = TS**2
      TS3 = TS**3
      TS4 = TS**4
      TS5 = TS**5
      CO  = A0 + A1*TS + A2*TS2 + A3*TS3 + A4*TS4 + A5*TS5
     $     + S*(B0 + B1*TS + B2*TS2 + B3*TS3)
     $     + C0*(S*S)
      o2sato = EXP(CO)
c
c  Convert from ml/l to mol/m^3
c
      o2sato = o2sato/22391.6*1000.0
C
      RETURN
      END