c_ ---------------------------------------------------------------------
c_ RCS lines preceded by "c_ "
c_ ---------------------------------------------------------------------
c_
c_ $Source: /home/orr/WWW/Abiotic/boundcond/RCS/read_c14atm.f,v $ 
c_ $Revision: 1.1 $
c_ $Date: 1999/04/26 13:52:31 $   ;  $State: Exp $
c_ $Author: orr $ ;  $Locker:  $
c_
c_ ---------------------------------------------------------------------
c_ $Log: read_c14atm.f,v $
c_ Revision 1.1  1999/04/26 13:52:31  orr
c_ Initial revision
c_
c_ ---------------------------------------------------------------------
c_ 
      SUBROUTINE read_c14atm (nc14rec, yrc14rec, atmc14rec)
C     ------------------------------------------------------------------
C     Reads temporal history of atmospheric C-14 (permil)
C     ------------------------------------------------------------------
c     ==================================================================
c     ARGUMENT LIST -
c     ===============
c     Note: Variable type is given in square brackets (below)
c     (r-real, i-integer, l-logical, c-character; s-scaler, a-array).
c     ===============
c     INPUT:
c     -------
c      none
c
c     OUTPUT: 
c     -------
c     [ia]  nc14rec    =  3-member array with the number of records
c                         of atmospheric C-14 in each of the 3 latitudinal
c                         bands listed below.
c     [ra]  yrc14rec   =  Sequential list of times (in decimal years)
c                         for when atmospheric C-14 data is available
c     [ra]  atmc14rec  =  Corresponding sequential list of atmospheric 
c                         C-14 (permil), in 3 latitudinal bands:
c                         (1) 90S - 20S,
c                         (2) 20S - 20N, and
c                         (3) 20N - 90N.
c                         This record is from Enting et al. (1994).
c     ==================================================================
c     
c     Reference
c     ---------
c     Enting, I.G., T. M. L. Wigley, M. Heimann, 1994. Future Emissions 
c     and concentrations of carbon dioxide: key ocean / atmosphere / 
c     land analyses, CSIRO Aust. Div. Atmos. Res. Tech. Pap. No. 31, 
c     118 pp.
c     ------------------------------------------------------------------      
c     James ORR, LSCE/CEA-CNRS, Saclay, France, 17 April 1999

      IMPLICIT NONE 

      INTEGER maxrec, nzon
      PARAMETER (maxrec=300, nzon=3)
      INTEGER luc14, irec, il

      INTEGER nc14rec(nzon)
      REAL yrc14rec(maxrec,nzon), atmc14rec(maxrec,nzon)

C     Open one FILE for each of 3 latitudinal bands
C     ---------------------------------------------
      luc14 = 50
      OPEN(luc14+1, FILE='c14sth.dat', FORM='formatted', STATUS='old')
      OPEN(luc14+2, FILE='c14equ.dat', FORM='formatted', STATUS='old')
      OPEN(luc14+3, FILE='c14nth.dat', FORM='formatted', STATUS='old')
c
c-----------------------------------------------------------------------
c       Get atmospheric C-14 data:
c-----------------------------------------------------------------------
        do il=1,3
c
c         Skip top 4 descriptor lines
          read(luc14+il,100)
  100     format(///)

          do irec=1,maxrec
            read(luc14+il, *,err=11,end=12)
     &                         yrc14rec(irec,il),atmc14rec(irec,il)
            nc14rec(il) = irec
          end do

   11     continue
          print *, 'Error in reading input file: unit = ',luc14+il-1
          print *, 'Sequential record number (irec) = ',irec

   12     continue
          WRITE(*,*) 'Atm. C-14: No. of entries in lat. band ',il,': ', 
     &              nc14rec(il)
          CLOSE(luc14+il)
        END DO

      RETURN
      END